:action1
say current_player "Tiene pinta de que fuma"

:action2
set_global loom_conversation_done false
#set_gui_visible false
#turn_to eneko_smoking player

?
	- "Quien eres tu?"
		say current_player "Quien eres tu?"
		say eneko_smoking "Soy Eneko" [!name_known]
		say eneko_smoking "Ya te he dicho mi nombre!!" [name_known]
		say eneko_smoking "NO PREGUNTES" [name_known]
		say eneko_smoking "NI ME CONTACTES POR WHATSAPP O TE BLOQUEARE" [name_known]
		set_global name_known true
	- "Que haces?"
		say current_player "Que haces aqui?"
		say eneko_smoking "Fumar"
		say eneko_smoking "no lo ves?"
	# This starts an inner subset of questions
	- "Can I ask you about Loom?" [!loom_conversation_done]
		say current_player 	"What do you know about Loom?"
		say eneko_smoking "What do you want to know about Loom?"
		?
		- "Could it be created in Escoria?" [!loom_conversation_done]
			say player	"Could Loom be created in Escoria?"
			say eneko_smoking	"Yes!"
		- "Is it a fun game?" [!loom_conversation_done, !fun_game_asked]
			say player	"Is Loom a fun game?"
			say eneko_smoking	"Yes!"
			set_global fun_game_asked true
		- "I don't want to talk at all any more." [!loom_conversation_done]
			#turn_to eneko_smoking worker_face_down
			stop
		# This will take you back to the outer set of questions
		- "I know enough about Loom." [!loom_conversation_done]
			set_global loom_conversation_done true
		!
	- "Agur"
		say player	"Agur yogur!"
		#turn_to eneko_smoking player
		stop
!
#set_gui_visible true

:action3 i_caja_herramientas
say eneko_smoking "No quiero una caja vacía"

:action3 i_bombona2
> [eq bombona2_offered 1]
	say eneko_smoking "¡No vuelvas a hacerlo, es peligroso!"
	set_global bombona2_offered 2
	stop
> [eq bombona2_offered 2]
	say eneko_smoking "¡SE ACABÓ, TE HE BLOQUEADO EN WHATSAPP!"
	stop
say eneko_smoking "¿Estás loco? ¿No ves que estoy fumando?"
set_global bombona2_offered 1
