:action1
say current_player "Tiene pinta de que fuma"

:intro_dialog
say current_player cocina_delante_intro_dialog_player:"Egunon! Que bien se duerme en este pueblo."
say eneko_smoking cocina_delante_intro_dialog_eneko:"Mira tú, el señorito se ha dignado a aparecer."
say eneko_smoking cocina_delante_intro_dialog_eneko_2:"¿Piensas hacer algo de provecho o te vas a pasar toda la mañana sentado fumando porros?"

?
  - cocina_delante_intro_dialog_option1:"Uyuyuy, parece que alguien se ha despertado con el pie izquierdo." [!cocina_delante_intro_dialog_option1_done]
    say_last_dialog_option
    say eneko_smoking cocina_delante_intro_dialog_option1_res:"Grr..."
    set_global cocina_delante_intro_dialog_option1_done true
  - cocina_delante_intro_dialog_option2:"En algunas culturas fumar se considera una actividad de provecho."
    say_last_dialog_option
    say eneko_smoking cocina_delante_intro_dialog_option2_res:"Con que sí, ¿eh? Dame un ejemplo listillo."
        set_global cocina_delante_intro_dialog_option2_done false
    ?
      - cocina_delante_intro_dialog_option2_1:"Los nativos americanos fumaban la pipa de la paz." [!cocina_delante_intro_dialog_option2_done, !cocina_delante_intro_dialog_option2_1_done]
        say_last_dialog_option
        say eneko_smoking cocina_delante_intro_dialog_option2_1_res:"Puede ser, pero tú no tienes pinta de nativo americano."
        set_global cocina_delante_intro_dialog_option2_1_done true
      - cocina_delante_intro_dialog_option2_2:"Históricamente el cannabis se ha utilizado para inducir experiencias espirituales." [!cocina_delante_intro_dialog_option2_done, !cocina_delante_intro_dialog_option2_2_done]
        say_last_dialog_option
        say eneko_smoking cocina_delante_intro_dialog_option2_2_res:"¿Colocarte y ver a los espíritus te parece hacer algo de provecho?"
        set_global cocina_delante_intro_dialog_option2_2_done true
      - cocina_delante_intro_dialog_option2_3:"Hay estudios que relacionan el consumo de cannabis con la revolución industrial del siglo XVIII." [!cocina_delante_intro_dialog_option2_done, !cocina_delante_intro_dialog_option2_3_done]
        say_last_dialog_option
        say eneko_smoking cocina_delante_intro_dialog_option2_3_res:"Eso no te lo crees ni tú."
        set_global cocina_delante_intro_dialog_option2_3_done true
      - cocina_delante_intro_dialog_option2_4:"Bueno, igual me he pasado con 'actividad de provecho'." [!cocina_delante_intro_dialog_option2_done]
        say_last_dialog_option
        say eneko_smoking cocina_delante_intro_dialog_option2_4_res:"Y que lo digas."
        set_global cocina_delante_intro_dialog_option2_done true
    !
  - cocina_delante_intro_dialog_option3:"Me gustaría comtemplar el paisaje y escribir un bonito poema sobre la vida en el campo." [!cocina_delante_intro_dialog_option3_done]
    say_last_dialog_option
    say eneko_smoking cocina_delante_intro_dialog_option3_res:"¿En qué cabeza cabe que eso pueda ser algo de provecho?"
    set_global cocina_delante_intro_dialog_option3_done true
  - cocina_delante_intro_dialog_option4:"Sería super guapo hacer un juego de ordenador sobre el día a día en el pueblo." [!cocina_delante_intro_dialog_option4_done]
    say_last_dialog_option
    say eneko_smoking cocina_delante_intro_dialog_option4_res:"No suena como algo super provechoso."
    set_global cocina_delante_intro_dialog_option4_done true
  - cocina_delante_intro_dialog_option:"El juego sería una aventura gráfica muy divertida." [cocina_delante_intro_dialog_option4_done,!cocina_delante_intro_dialog_option5_done]
    say_last_dialog_option
    say eneko_smoking cocina_delante_intro_dialog_option5_res:"Deja que lo dude, las aventuras gráficas son aburridísimas."
    say eneko_smoking cocina_delante_intro_dialog_option5_res2:"Lo que mola es matar marcianitos."
    set_global cocina_delante_intro_dialog_option5_done true
  - cocina_delante_intro_dialog_option:"Podrías salir en el juego si quisieras." [cocina_delante_intro_dialog_option5_done,!cocina_delante_intro_dialog_option6_done]
    say_last_dialog_option
    say eneko_smoking cocina_delante_intro_dialog_option6_res:"Hmm, lo del juego no suena tonto del todo..."
    say eneko_smoking cocina_delante_intro_dialog_option6_res2:"¿Puedes hacer que fume sin parar?"
    say current_player cocina_delante_intro_dialog_option6_res_player:"¡Claro, es muy fácil!"
    say eneko_smoking cocina_delante_intro_dialog_option6_res3:"¿Y podrías meter imágenes subliminales para que la gente haga lo que quiera?"
    say current_player cocina_delante_intro_dialog_option6_res_player2:"No veo por que no, la mayoría de juegos lo hacen, es una práctica habitual en la industria."
    say eneko_smoking cocina_delante_intro_dialog_option6_res4:"Suena interesante, ya hablaremos más adelante, pero para hoy tienes que pensar otra cosa que hacer."
    set_global cocina_delante_intro_dialog_option6_done true
  - cocina_delante_intro_dialog_end:"¿Que te parece que haga la comida?"
    say_last_dialog_option
    say eneko_smoking cocina_delante_intro_dialog_end_res:"Hmm, podría servir, pero no te pases con la cantidad, no quiero estar cinco días comiendo lo mismo."
    say current_player cocina_delante_intro_dialog_end_res_player:"¡Ningún problema! En cuanto decida que hacer de comer me pongo a cocinar."
    stop
  # - cocina_delante_intro_dialog_option:"" [!cocina_delante_intro_dialog_option_done]
  #   say_last_dialog_option
  #   say eneko_smoking cocina_delante_intro_dialog_option_res:""
  #   set_global cocina_delante_intro_dialog_option_done true
!

:action2
> [whatsapp_blocked]
	say current_player "Hola..."
	say current_player "No me escucha, parece que me tiene bloqueado"
	stop

#set_gui_visible false
#turn_to eneko_smoking player

?
	- "Quien eres tu?"
		say current_player "Quien eres tu?"
		say eneko_smoking "Soy Eneko" [!name_known]
		say eneko_smoking "Ya te he dicho mi nombre!!" [name_known]
		say eneko_smoking "NO PREGUNTES" [name_known]
		say eneko_smoking "NI ME CONTACTES POR WHATSAPP O TE BLOQUEARE" [name_known]
		set_global name_known true
	- "Que haces?"
		say current_player "Que haces aqui?"
		say eneko_smoking "Fumar"
		say eneko_smoking "No lo ves?"
	- "Agur"
		say current_player	"Agur yogur!"
		#turn_to eneko_smoking player
		stop
!
#set_gui_visible true

:action3 caja_herramientas
> [caja_herramientas_with_wrench]
	inventory_remove caja_herramientas
	say eneko_smoking "Gracias majo!"
	say eneko_smoking "Te voy a desbloquear de whatsapp" [whatsapp_blocked]
	set_global whatsapp_blocked false
	stop
say eneko_smoking "No quiero una caja vacía" [!caja_herramientas_with_wrench]

:action3 bombona2
> [eq bombona2_offered 1]
	say eneko_smoking "¡No vuelvas a hacerlo, es peligroso!"
	set_global bombona2_offered 2
	stop
> [eq bombona2_offered 2]
	say eneko_smoking "¡SE ACABÓ, TE HE BLOQUEADO EN WHATSAPP!"
	set_global whatsapp_blocked true
	stop
say eneko_smoking "¿Estás loco? ¿No ves que estoy fumando?"
set_global bombona2_offered 1

:action3 turno_cocina_frontal
> [!turno_cocina_frontal_debajo_sofa]
  say eneko_smoking "No tengas prisa por devolvérmela, aun puede serte de utilidad."
  say eneko_smoking "(guiño, guiño)"
  stop
> [turno_cocina_frontal_debajo_sofa]
	inventory_remove turno_cocina_frontal
  say eneko_smoking "Menos mal, no tiene ni un rasguño."
  say eneko_smoking "Le tengo mucho cariño. Te he contado que me la regaló mi abuelo?"
  say eneko_smoking "Espera... fue el abuelo o la tía?"
  say eneko_smoking "Bueno, no me acuerdo, fue hace mucho tiempo."
  say eneko_smoking "Pero es mía, eso seguro."
  say eneko_smoking "De toda la vida."

:action3 turno_cocina_madera
say current_player "Quieres leña?"
say eneko_smoking "Andas buscando pelea?"
say eneko_smoking "Te advierto que soy cinturón negro de Kung Fu!"
?
  - "No, no. Solo te ofrecía un trozo de leña." [!eneko_madera_option1_done]
    say_last_dialog_option
    say eneko_smoking "Y que quieres que haga con un leño?"
    say eneko_smoking "No se te ha ocurrido que si quisiera leña iría a por ella?"
    say eneko_smoking "Acaso te he pedido leña?"
    say current_player "Vale, pillo la idea."
    say current_player "Yo..."
    say current_player "creía que te gustaría..."
    say eneko_smoking "Ya lo siento, a veces soy un borde."
    say eneko_smoking "Pero es que era una idea de mierda."
    set_global eneko_madera_option1_done true
  - "Has dicho cinturón negro de Kung Fu?" [!eneko_madera_option2_done]
    say_last_dialog_option
    say eneko_smoking "Sí, es lo que he dicho."
    say current_player "Kung Fu? No querrías decir Karate?"
    say eneko_smoking "Pues no, quería decir Kung Fu."
    say current_player "No sabía que había cinturón negro de Kung Fu."
    say eneko_smoking "Pues mira, ya lo sabes."
    set_global eneko_madera_option2_done true
  - "Te veo muy tenso, creo que deberías trabajar tu mal humor." [!eneko_madera_option3_done]
    say_last_dialog_option
    say eneko_smoking "Grrr."
    set_global eneko_madera_option3_done true
  - "Creo que me voy a alejar muy despacio..."
    say_last_dialog_option
    say eneko_smoking "Bien haces, no durarías ni un segundo."
    say eneko_smoking "Me he visto todas las películas de Bruce Lee."
    say eneko_smoking "Varias veces."
    stop
